Warnhinweis, wenn Patienten zu früh oder zu spät zum Termin erscheinen

Koopmann

Hallo zusammen,

ich such nach einer Aktionskettenbedingung durch die ein Warnhinweis erscheint, wenn der Patient zu früh oder auch zu spät zum vereinbarten Termin erscheint. Kann jemand helfen?

LG Mario Koopmann

Jonas Kortemeier

Das Problem habe ich auch. Meine MFAs sehen im Trubel nicht immer, ob ein Patient pünktlich ist und weisen dadurch nicht immer Spätzügler ab. Meine Idee war über die AK-Bedingungen zu gehen:

$[uhrzeitAktuellerTermin]$ ist kleiner als $[d S HH:mm -5m]$

Problem hierbei: Vergleiche mit hh:mm scheinen nicht zu funkionieren.

Gibt es hier von Zollsoft die Möglichkeit sowohl $[uhrzeitAktuellerTermin]$ als auch $[d]$ als zB Unix-Zeit/Seconds Since Midnight oder Time Of Day in Sekunden auszugeben?

Oder hat jemand eine andere Idee? Vielen Dank!

Hans Jörg Baumann

Moin,

die Problematik trieb mich auch immer schon rum, daher vielen Dank für den Anstoß zum Basteln.

Tatsächlich funktionieren Uhrzeit-Vergleiche in AK nicht, da aus "15:20" im Vergleich bei größer/kleiner (also Zahlen) dann "15" wird. Falls es da nicht doch eine tomedo-eigene Lösung gibt, geht das hier nicht.

Mittels AppleScript kann man das aber doch lösen. Das Script gibt einen Text wie "5 min zu spät" aus und packt diesen in die Zwischenablage. Von da kann man ihn z.B. in das Besuchsinfo-Feld schreiben, dann steht (für alle Ewigkeit dokumentiert in der Akte...), wieviel Minuten zu früh/zu spät der Pat. kam. Wenn man will, könnte man das auch als Karteieintrag ablegen, um eine Statistik daraus zu machen.

-- Uhrzeit des geplanten Termins (z.B. "14:30")

set terminZeitText to "$[uhrzeitAktuellerTermin]$"

-- Aktuelle Uhrzeit laut tomedo (z.B. "14:25")

set jetztZeitText to "$[d S HH:mm]$"



set terminMinuten to minutenSeitMitternacht(terminZeitText)

set jetztMinuten to minutenSeitMitternacht(jetztZeitText)



-- positiv = Patient ist zu früh, negativ = Patient ist zu spät

set minutenVorTermin to terminMinuten - jetztMinuten



-- Toleranzbereich, innerhalb dessen der Patient als "pünktlich" gilt

set toleranzMinuten to 5



set ergebnisText to ""

if minutenVorTermin > toleranzMinuten then

	set ergebnisText to (minutenVorTermin as text) & " min zu früh"

else if minutenVorTermin < -toleranzMinuten then

	set ergebnisText to ((minutenVorTermin * -1) as text) & " min zu spät"

else

	set ergebnisText to "pünktlich"

end if



set the clipboard to (ergebnisText as text)

display dialog (ergebnisText as text)



return ergebnisText



on minutenSeitMitternacht(zeitText)

	set alterDelimiter to AppleScript's text item delimiters

	set AppleScript's text item delimiters to ":"

	set std to (text item 1 of zeitText) as integer

	set min to (text item 2 of zeitText) as integer

	set AppleScript's text item delimiters to alterDelimiter

	return std * 60 + min

end minutenSeitMitternacht

Kartei:

Tagesliste:

Karteieintrag BES:

Jonas Kortemeier

Sehr cool! Vielen Dank! Ans Apple Skript habe ich einfach nicht gedacht. Der Umweg ist genial!

Hans Jörg Baumann

Kleine Korrektur zum Applescript. Die erste Variante berücksichtigte nicht den Fall "Pat. kommt ohne Termin", dann wäre die Variable $[uhrzeitAktuellerTermin]$ leer, was zu Fehlern führte.

Daher hier nun eine korrigierte Version des Scripts. Wenn kein Termin existiert am Besuchstag, wird einfach auch nichts ausgegeben.

Die Formatierung mit <<Minuten-zum-Termin>> neben dem Eintrag "xx min zu spät" habe ich mir ergänzt, um einfacher Statistiken zur Verspätungsproblematik machen zu können. Wenn man mit der tomedo-eigenen Statistik-Funktion arbeiten will für diesen Zweck, ist wahrscheinlich die Anlage eines eigenen Karteieintrags z.B. ZEIT-ZU-TERMIN sinnvoller / einfacher, bedeutet aber halt auch nochmal einen Eintrag mehr pro Besuch.

-- Uhrzeit des geplanten Termins (z.B. "14:30"), kann leer sein, wenn kein Termin vorliegt

set terminZeitText to "$[uhrzeitAktuellerTermin]$"

-- Aktuelle Uhrzeit laut tomedo (z.B. "14:25")

set jetztZeitText to "$[d S HH:mm]$"



set toleranzMinuten to 5



if terminZeitText is "" then

	-- Patient kommt ohne Termin

	set minutenVorTermin to 0

	set ergebnisText to "<<0>>"

else

	set terminMinuten to minutenSeitMitternacht(terminZeitText)

	set jetztMinuten to minutenSeitMitternacht(jetztZeitText)

	

	-- positiv = Patient ist zu früh, negativ = Patient ist zu spät

	set minutenVorTermin to terminMinuten - jetztMinuten

	

	if minutenVorTermin > toleranzMinuten then

		set ergebnisTextInhalt to (minutenVorTermin as text) & " min zu früh"

	else if minutenVorTermin < -toleranzMinuten then

		set ergebnisTextInhalt to ((minutenVorTermin * -1) as text) & " min zu spät"

	else

		set ergebnisTextInhalt to "pünktlich"

	end if

	

	set ergebnisText to "<>" & ergebnisTextInhalt & "<<" & minutenVorTermin & ">>"

end if



set the clipboard to ergebnisText



return ergebnisText



on minutenSeitMitternacht(zeitText)

	set alterDelimiter to AppleScript's text item delimiters

	set AppleScript's text item delimiters to ":"

	set std to (text item 1 of zeitText) as integer

	set min to (text item 2 of zeitText) as integer

	set AppleScript's text item delimiters to alterDelimiter

	return std * 60 + min

end minutenSeitMitternacht